＊＊＊＊　ＬＣＤディスプレィの接続  ＊＊＊

下記のようにデータラインとコントロールラインを接続して下さい。

 8255 PORT-A (data bus )   8255 PORT-B  (ctrl lines)
                LM16257                   LM16257
    CN8-1  ------ 7,DB0       CN9-1  ------ 6,E Enable
    CN8-2  ------ 8,DB1       CN9-2  ------ 5,R/W Read/Write
    CN8-3  ------ 9,DB2       CN9-3  ------ 4,RS Register Select
    CN8-4  ------10,DB3
    CN8-5  ------11,DB4       CN14-2 ------ 2,VDD +5v
    CN8-6  ------12,DB5       CN14-1 ------ 1,VSS
    CN8-7  ------13,DB6                     3,VO Contrast
    CN8-8  ------14,DB7                      10K-20KOHM VR center
                                               between VDD and CN14-19-12V

ＬＭ１６２５７のピン１はコネクターの内側になります。誤ると壊してしまいます。
接続には注意して下さい。

７４ＬＳ６４０のドライバーレシーバは入出力に対して反転論理です。
７４ＬＳ６４５を使用のこと。

100 REM *** LM16257 ***
101 REM *** 8255 BASE ADR 0E100H, PORT A0-A7=LCD PIN DB0- DB7
102 REM *** PORT B0-B2=LCD PIN E,R/W,RS
110 STRING 400,40
120 P0=0E100H : P1=P0+1 : P2=P0+2 : P3=P0+3
130 REM *** 8255 MODE SET OUT PUT ***
140 XBY(P3)=80H : REM *** PORT A,B,C OUT
150 REM *** LM16257 8 BIT INIT ***
160 GOSUB 260
170 REM *** MAIN ***
180 $(1)= "LCD DEMO"  : GOSUB 340 : REM ** ASCII
200 $(1)= "91.8.18"  : GOSUB 340 : REM ** ASCII
210 XBY(P0)=0C0H : GOSUB 320 : REM ** DDRAM ADR 40 CR/LF
220 INPUT $(1) : GOSUB 340
230 XBY(P0)=002H : GOSUB 320 : REM ** HOME
240 INPUT $(1) : GOSUB 340
250 STOP : END
260 REM *** LM16257 8 BIT MODE SET ***
270 XBY(P0)=38H : GOSUB 320 : REM ** FUNCTIONAL SET 8 BIT 2 LINE
280 XBY(P0)=0FH : GOSUB 320 : REM ** DISPLAY CTRL COURSER  ON
290 XBY(P0)=06H : GOSUB 320 : REM ** ENTRY MODE INCL.
300 XBY(P0)=01H : GOSUB 320 : REM ** DISPLAY CLEAR
310 RETURN
320 REM *** COMMAND WRITE  INST R  AND E SIGNAL ***
330 XBY(P1)=1H : XBY(P1)=0H : RETURN
340 REM *** DIPLAY DATA ***
350 FOR X=1 TO 16
360 LD=ASC($(1),X)
370 IF LD=0DH THEN 430 :REM CR ?
390 XBY(P0)=LD
400 REM *** DATA WRITE = DATA RG AND ENABLE SIGNAL
410 XBY(P1)=05H : XBY (P1)=04H
420 NEXT
430 RETURN